#!/usr/bin/guile \
-e "(scripts render-bugs)" -s
!#
;;; render-bugs --- Display bugs db contents in various ways

;; 	Copyright (C) 2002,2003,2004 Free Software Foundation, Inc.
;;
;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation; either version 2, or
;; (at your option) any later version.
;;
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;; General Public License for more details.
;;
;; You should have received a copy of the GNU General Public License
;; along with this software; see the file COPYING.  If not, write to
;; the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
;; Boston, MA 02110-1301, USA.
;;
;; As a special exception, the Free Software Foundation gives permission
;; for additional uses of the text contained in its release of GUILE.
;;
;; The exception is that, if you link the GUILE library with other files
;; to produce an executable, this does not by itself cause the
;; resulting executable to be covered by the GNU General Public License.
;; Your use of that executable is in no way restricted on account of
;; linking the GUILE library code into it.
;;
;; This exception does not however invalidate any other reasons why
;; the executable file might be covered by the GNU General Public License.
;;
;; This exception applies only to the code released by the
;; Free Software Foundation under the name GUILE.  If you copy
;; code from other Free Software Foundation releases into a copy of
;; GUILE, as the General Public License permits, the exception does
;; not apply to the code that you add in this way.  To avoid misleading
;; anyone as to the status of such modified files, you must delete
;; this exception notice from them.
;;
;; If you write modifications of your own for GUILE, it is your choice
;; whether to permit this exception to apply to your modifications.
;; If you do not wish that, delete this exception notice.

;;; Author: Thien-Thi Nguyen <ttn@gnu.org>

;;; Commentary:

;; Usage: render-bugs [BUGS-DB-DIR]
;;
;; Display the headers of the bug files in ../workbook/bugs/
;; (or BUGS-DB-DIR if specified).
;;
;;
;; Usage from a Scheme program:
;;  (render-bugs [DIR])
;;
;;
;; TODO: Add --html and --details support.

;;; Code:

(define-module (scripts render-bugs)
  #:autoload (scripts PROGRAM) (HVQC-MAIN)
  #:autoload (scripts read-rfc822) (read-rfc822-silently)
  #:export (render-bugs))

(define (top-level-bug-files dir)       ; todo: generalize
  (chdir dir)
  (let ((d (opendir "."))
        (rx (make-regexp "[a-z0-9]+")))
    (let loop ((file (readdir d)) (acc '()))
      (if (eof-object? file)
          (sort acc string<?)
          (loop (readdir d)
                (cond ((file-is-directory? file) acc)
                      ((regexp-exec rx file) (cons file acc))
                      (else acc)))))))

(define (render-bug-file file)
  (simple-format #t "name: ~A\n" file)
  (let ((q (read-rfc822-silently (open-input-file file))))
    (for-each (lambda (header)
                (simple-format #t "~A: ~A\n" (car header) (cdr header)))
              (q 'headers)))
  (newline))

(define (render-bugs . dir)
  (set! dir (if (null? dir) "../workbook/bugs" (car dir)))
  (or (and (file-exists? dir)
           (file-is-directory? dir))
      (error "no such directory:" dir))
  (simple-format #t "Guile BUGS database snapshot: ~A UTC.\n"
                 (strftime "%Y-%m-%d %H:%M:%S" (gmtime (current-time))))
  (simple-format #t "~A (~A).\n\n"
                 "Please send bug reports to bug-guile@gnu.org"
                 "after checking this list")
  (for-each render-bug-file (top-level-bug-files dir))
  #t)

(define (main args)
  (HVQC-MAIN args (lambda (args)
                    (apply render-bugs (cdr args)))
             '(usage . commentary)
             '(package . "Guile")))

;;; render-bugs ends here
